File:COVID-19-Pandemie - PW (Palau) - Tote (800px).svg
頁面內容唔支援其他語言。
出自維基百科,自由嘅百科全書
呢個「SVG」檔案嘅呢個「PNG」預覽嘅大細:800 × 450 像素。 第啲解像度:320 × 180 像素|640 × 360 像素|1,024 × 576 像素|1,280 × 720 像素|2,560 × 1,440 像素。
原本檔案 (SVG檔案,表面大細: 800 × 450 像素,檔案大細:452 KB)
摘要
描述COVID-19-Pandemie - PW (Palau) - Tote (800px).svg |
Deutsch: COVID-19-Pandemie - PW (Palau) - Tote (800px) |
||
日期 | laufende Aktualisierungen | ||
來源 | Daten von der WHO - https://covid19.who.int/WHO-COVID-19-global-data.csv - durch Klicken auffindbar über https://covid19.who.int/table | ||
作者 | Summer ... hier! | ||
SVG genesis InfoField | This COVID-19 chart was created with Gnuplot. This plot uses embedded text that can be easily translated using a text editor. | ||
原始碼 InfoField |
# input (Zeitformat und Separator definieren)
#
set timefmt "%Y-%m-%d"
set datafile separator ';'
# Variablen zeile_X_stat setzten
# (every ::0 steht für 'ab erster Zeile' und kann weggelassen werden)
stats $WHO_data every ::0 using 5 name "zeile_5_stat" nooutput
stats $WHO_data every ::0 using 6 name "zeile_6_stat" nooutput
stats $WHO_data every ::0 using 7 name "zeile_7_stat" nooutput
stats $WHO_data every ::0 using 8 name "zeile_8_stat" nooutput
# Start und Ende ermitteln und Label setzen (incl. Konsolenausgabe)
stats $WHO_data every ::0 u (strptime("%Y-%m-%d",strcol(1))) name "datum" nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",datum_min)
print ' Ende: ', strftime("%d. %B %Y",datum_max)
print ' --------------------------'
# label fuer Grafikueberschrtft oben links mit den ermittelten Werten setzen
set label 'Daten vom '.strftime("%d.%m.%y",datum_min).' bis '.strftime("%d.%m.%y",datum_max) at graph 0.03, graph 0.93
# als Workaround nehmen wir statt zweimal 'ylabel' hier zweimal 'label'
# (bei multiplot ist es schwierig fuer alle Plots ein ylabel mit gleichen seitl. Einzug zu finden)
set label "Tote (kumuliert)" at screen 0.017, 0.700 rotate by +90 center
set label "Tote" at screen 0.017, 0.300 rotate by +90 center
# output
#
# Name der SVG-Datei
set output 'COVID-19-Pandemie_-_PW_(Palau)_-_Tote_(800px).svg'
unset key # keine Box fuer Legende
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set xtics scale 0.7, 0.4 # Skalenstriche x-Achse etwas kleiner
set ytics scale 0.7, 0.4 # Skalenstriche y-Achse etwas kleiner
set ytics offset 0.4, 0.0 # Zahlen eine Idee nach rechts (mehr Abstand vom Label)
# 'Wasserzeichen' für commonsprüfung
set label 'PW' at screen 0.01, 0.02 textcolor rgb '#ffffff' font 'Arial,8'
# Gitterlinienen per Hand setzen
set style line 1 linetype rgb '#4f4f4f' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#9f9f9f' linewidth 0.20 # def. Minor-grid
unset grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse (Monate)
set grid x2tics nomx2tics # Gitterliniene an der 2. X-Achse (Kalenderwochen)
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle fuer Major u. Minor
# X-Achsenbeschriftung:
# ueber x1 machen wir die Monatsbschriftung, ueber x2 die Kalenderwochenbeschriftung
#
# beide X-Achsen, also x1 und x2, als Zeitachse definieren
set xdata time
set x2data time
# Bereich (von - bis) der X-Achse definieren
# Beginnt am 1. Jan. 2020 und Edit heute plus 6 Tage
xrange_max=strftime("%Y-%m-%d", time(0) + (60*60*24*6))
# zuvor Berechnetes xrange_max setzten
set xrange ['2020-01-01': xrange_max]
set x2range ['2020-01-01': xrange_max]
# die Maker fuer Monat setzen wir per Hand. Als 'format' geben wir einen leeren String an damit
# kein Text generiert wird (fuer die untere Grafik setzen wir den Text spaeter)
set xtics format "" # Format auf Nichts damit gnuplot die folgenden Daten nicht aufloest
set xtics ( "2020-01-01" \
, "2020-02-01" \
, "2020-03-01" \
, "2020-04-01" \
, "2020-05-01" \
, "2020-06-01" \
, "2020-07-01" \
, "2020-08-01" \
, "2020-09-01" \
, "2020-10-01" \
, "2020-11-01" \
, "2020-12-01" \
, "2021-01-01" \
, "2021-02-01" \
, "2021-03-01" \
)
#
# Kalenderwochen-Striche
#
# fuer x2 (KW) ebendalls keine Beschriftung
set format x2 ''
# der 6. Jan. 2020 war ein Montag - da setzen wir den ersten Strich und die
# folgenden Striche alle 7 Tage (hier in 60 * 60 * 24 * 7 Sekunden)
set x2tics '2020-01-06', 60 * 60 * 24 * 7
set x2tics scale 0
set xtics nomirror
unset mxtics
# Format Y-Achse
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
set yrange [-2:10]
set ytics 10
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2020-%1.2d-01",i)
marker_stop =sprintf("2020-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
marker_start=sprintf("2021-%1.2d-01",i)
marker_stop =sprintf("2021-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
# Groesse und Schrift definieren
#
# Zur Variablen 'datum_max' siehe oben
my_svg_name=strftime("COVID_%d_%m_%Y_PW",datum_max)
set term svg size 800,450 font "Arial,16" name my_svg_name
###########################################################################################
set lmargin 10.0 # linker Rand fuer Beschriftung Y-Achse sollte nicht auf Auto stehen
set rmargin 1.0 # rechter Rand
set tmargin 1.0 # top margin
set bmargin 0.0 # bottom margin
set multiplot
# Ausgabe oberer Graph
set size 1.000, 0.550 # Groesse der Grafik
set origin 0.000, 0.450 # def. der linken unteren Ecke
unset xlabel
plot $WHO_data usi 1:8 axis x1y1 tit 'Infizierte' lt rgb '#700070' lw 1.75 with lines
# Ausgabe unterer Graph
set tmargin 0.4 # Wert von oben ueberschreiben damit Grafiken enger zusammen
unset bmargin # oben wurde bottommargin auf null gesetzt - jetzt wieder auto damit Platz fuer Skala
unset label #
set size 1.000, 0.450
set origin 0.000, 0.000
# Wenn das Datumsintervall so gross wird das die Labels zu eng gesetzt sind
# hier jeden zweiten Eintrag loeschen!
set xtics rotate by +30 center offset -1.5,-0.6
set xtics add ( " 2020" "2020-01-01" \
, "1. Feb." "2020-02-01" \
, "1. März" "2020-03-01" \
, "1. Apr." "2020-04-01" \
, "1. Mai" "2020-05-01" \
, "1. Jun." "2020-06-01" \
, "1. Jul." "2020-07-01" \
, "1. Aug." "2020-08-01" \
, "1. Sep." "2020-09-01" \
, "1. Okt." "2020-10-01" \
, "1. Nov." "2020-11-01" \
, "1. Dez." "2020-12-01" \
, " 2021" "2021-01-01" \
, "1. Feb." "2021-02-01" \
, "1. März" "2021-03-01" \
)
set xlabel "Datum (Monats- und KW-Skala)"
set yrange [-1:5]
set ytics 5
set mytics 5
# Ueber den Wert von lw kann man die Sichtbarkeit bei kl. Aufl. regulieren
plot $WHO_data usi 1:7 axis x1y1 tit '' lt rgb '#700070' lw 0.75 with impulses
unset multiplot
|
協議
我,呢份作品嘅作者,決定用以下許可發佈呢件作品:
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Items portrayed in this file
圖中顯示嘅係
image/svg+xml
462,377 字節
450 像素
800 像素
檔案歷史
撳個日期/時間去睇響嗰個時間出現過嘅檔案。
日期/時間 | 縮圖 | 尺寸 | 用戶 | 註解 | |
---|---|---|---|---|---|
現時 | 2023年12月26號 (二) 13:43 | 800 × 450(452 KB) | Summer ... hier! | update | |
2023年10月29號 (日) 21:48 | 800 × 450(436 KB) | Summer ... hier! | update | ||
2023年10月6號 (五) 07:22 | 800 × 450(430 KB) | Summer ... hier! | update | ||
2023年9月23號 (六) 16:57 | 800 × 450(425 KB) | Summer ... hier! | update | ||
2023年9月6號 (三) 18:41 | 800 × 450(422 KB) | Summer ... hier! | update | ||
2023年8月24號 (四) 15:41 | 800 × 450(417 KB) | Summer ... hier! | update | ||
2023年8月17號 (四) 07:48 | 800 × 450(415 KB) | Summer ... hier! | update | ||
2023年8月10號 (四) 09:42 | 800 × 450(413 KB) | Summer ... hier! | update | ||
2023年8月3號 (四) 00:40 | 800 × 450(411 KB) | Summer ... hier! | update | ||
2023年7月27號 (四) 11:41 | 800 × 450(410 KB) | Summer ... hier! | update |
檔案用途
以下嘅1版用到呢個檔:
全域檔案使用情況
下面嘅維基都用緊呢個檔案:
- de.wikipedia.org嘅使用情況
- en.wikipedia.org嘅使用情況
- fr.wikipedia.org嘅使用情況
- zh.wikipedia.org嘅使用情況
Metadata
呢個檔案有額外嘅資料。佢應該係數碼相機或者掃描器整出來嘅。如果佢整咗之後畀人改過,裏面嘅資料未必同改過之後相符。
短標題 | COVID_19_12_2023_PW |
---|---|
圖名 | Produced by GNUPLOT 5.0 patchlevel rc2 |
闊 | 800 |
高 | 450 |